Forums XLPages

Excel & VBA Espace Débutants [résolu] Récupération de données turfiques du site gény course

Récupération de données turfiques du site gény course
#1
chakir123
Aspirant XLPages

Inscription: 05/10/2011

Messages: 35

Système d'exploitation:
PC
Version Excel utilisée:
2003, 2007
Posté le : 05-10-2011 17h17

Bonjour à tous,

Je ne sais pas si je suis dans le bon post, je m'en excuse si ce n'est pas le cas.
Etant amateur de turf j'ai un soucis pour récupérer certaines données via le site genycourse.com.
Comme je sais que Didier a déjà développé des fichiers de récupération de données turfiques (paris turf, turfoo, etc...), je me permets donc de vous solliciter.

Ci-joint mon tableau pour lequel je saisie chaque jour les données depuis 1 an, fastidieux!

Mon souhait :

Avoir un premier onglet permettant permettant d'importer toutes les réunions ou courses du jour soit du site gény courses ou comme je le fais du site TURFOMANIA.com, un peu comme vous l'aviez fait pour le fichier mDF récup web paris turf.

Ensuite j'aimerais avoir pour chaque course mon fameux tableau(turfomania), qui présente quelques incohérences à résoudre, notamment :

L'importation du tableau des partants (bleue), de manière automatique pour éviter le copier coller pour chacune des course a étudier soit du site gény ou turfomania

La musique du cheval a transformer en numérique de P1 à P6(orange), sachant que la musique se lit de gauche à droite, il y a un soucis concernant celle présente sur mon tableau (j'ai effacé des colonnes) et je n'arrive pas a reformuler.

Import de la carrière du cheval (nombres de courses, victoires, places) en bleu, on l'obtient sur le site de geny en cliquant sur le cheval, les côtes de références si possible mais pour ma part ce n'est que secondaire (a laisser tomber si trop compliqué).

Ensuite viennent mes calculs perso, dans le calcul de l'IC, j'ai besoin de la case de l'age du cheval, mais sans considération du sexe du cheval sinon ça m'inscrit "VALEUR".

Je sais que pour quelqu'un qui n'est pas turfiste ça peut être vu comme du charabia, ceci dit je suis patient et je suis prêt a donner des infos complémentaires. Sachant que pour ma part ce qui compte le plus c'est l'importation de la carrière, sinon le reste est libre de toutes imaginations.
N'étant pas spécialiste en la matière toutes vos idées sont la bienvenues.

Merci à vous.



Pièce jointe:
xls RécupWeb turfomania-geny.xls   [ Taille: 58.50 Ko - Téléchargements: 3030 ]
Hors Ligne
 Rapport   Haut 

Re: Récupération de données turfiques du site gény course
#2
myDearFriend!
Webmestre

Inscription: 18/05/2006
De Saône-et-Loire (71)

Messages: 1539

Système d'exploitation:
PC
Version Excel utilisée:
97, 2000, 2002, 2003, 2007, 2010, 2013, 2016 et 365
Posté le : 06-10-2011 00h16
Bonsoir chakir123, bienvenue sur XLpages.com

Personnellement, je ne suis pas sûr d'avoir suffisamment de disponibilité pour me pencher sur ta demande...

Tu l'as compris, ici on n'est pas forcément spécialiste turf (mais si ça continue, on va finir par le devenir )

Aussi, si tu veux qu'on t'aide, commence donc par nous donner les bonnes URL des sites de Turf cibles :
  • Chez moi, Genycourse.com m’amène sur un site qui ressemble guère à ce que tu décris... par contre Geny.com semble être un peu plus parlant. Qu'en est-il ?
  • Pareil pour Turfomania.com, chez moi ça ressemblerait plus à Turfomania.fr... (?)

Ensuite donne-nous aussi la marche à suivre sur ces sites pour accéder à tes données cibles.

Au final, si tu souhaites un traitement de récup Web, il va falloir trancher et choisir l'un ou l'autre de ces 2 sites. Mettre au point une procédure n'est pas toujours évident et s'il faut, en plus, coordonner et concaténer des prélèvements issus de l'un ET de l'autre, je doute qu'on s'en sorte simplement...

Cordialement,
Didier_mDF
Image redimensionnée
Le Webmaster

La réponse vous satisfait ? Merci de revenir solder le sujet en [résolu], voir ce lien
Hors Ligne
 Rapport   Haut 

Re: Récupération de données turfiques du site gény course
#3
chakir123
Aspirant XLPages

Inscription: 05/10/2011

Messages: 35

Système d'exploitation:
PC
Version Excel utilisée:
2003, 2007
Posté le : 06-10-2011 11h34

Bonjour Didier,

Tout d'abord je tiens à te remercier pour ta réactivité. Effectivement tu as bien compris et cibler parfaitement les deux sites.
Ceci dit afin de simplifier et faciliter la récupération des donnés nous conserveront à ce moment que le site : www.geny.com.
Lorsqu'on arrive sur l'accueil du site on se rend sur la page onglet quinté+/réunions pmu
http://www.geny.com/reunions-courses-pmu

Ensuite il y a toutes les réunions du jour dont nous avons besoin, composée de plusieurs courses. Après il suffit de cliquer sur les courses, par exemple :

http://www.geny.com/partants-pmu/2011 ... s-buttes-chaumont_c386349

On obtient un tableau de partants, c'est ce que je souhaite récupérer pour chaque course.
Pour avoir la carrière du cheval il suffit de cliquer sur le nom du cheval (sancho du parc le n°1) : http://www.geny.com/cheval/sancho-du-parc_c386349_h2083697

et là nous avons la carrière du cheval, mais ce qui m'intéresse c'est juste la synthèse de la carrière et non pas le détail, pour notre exemple ça se limite à ça :

Carrière

Courues

Victoires

Places

Courses

26

4

8


C'est tout ce dont j'ai besoin, rien de plus.

Précisions : Selon si c'est du trot, du plat ou de l'obstacle, le nombre de colonnes varient dans le tableau des partants, ce qui peut poser problème peut être pour les emplacements des formules de mon fichier excel je suppose.
Après nous ne sommes pas obligé d'importer toutes les réunions d'un coup (comme le fichier que tu avais réalisé avec le paris turf), si par exemple un premier onglet permettant de sélectionner la date et une course dans un menu déroulant ça sera tout bénef (comme celui que tu avais fait pour récupérer les données du site pmu).
Et si il faut faire 3 onglets pour chaque discipline pour éviter que mes formules changent de colonne car les colonnes du tableau des partants varient alors il en sera ainsi.

Je suis prêt à verser une contribution financière (don) s'il le faut, merci à toi Didier pour ce que tu fais.
Hors Ligne
 Rapport   Haut 

Re: Récupération de données turfiques du site gény course
#4
myDearFriend!
Webmestre

Inscription: 18/05/2006
De Saône-et-Loire (71)

Messages: 1539

Système d'exploitation:
PC
Version Excel utilisée:
97, 2000, 2002, 2003, 2007, 2010, 2013, 2016 et 365
Posté le : 17-10-2011 00h25
Bonsoir chakir123, le Forum,

Bon, je ne t'avais pas oublié, j'ai malheureusement très peu de temps disponible depuis quelques temps...

Tu trouveras en pièce jointe un tentative de réponse à ton besoin, qui j'espère pourra te satisfaire car, bien occupé par ailleurs, je ne peux me permettre d'investir plus de temps sur ta demande.

Pour information, j'ai utilisé le code VBA suivant :
Option Explicit
'---------------------------------------------------------------------------------------
' Auteur    : Didier FOURGEOT (myDearFriend!)  -  www.mdf-xlpages.com
' Date      : 16/10/2011
' Sujet     : Récup données Web : Geny.com
'---------------------------------------------------------------------------------------
Sub ListeCourses()
Dim IE As InternetExplorer
Dim IEdoc As HTMLDocument
Dim O As Object
Dim vUrl As String, T As String
    'Prépare la feuille
    ActiveSheet.Range("15:100").Delete
    Application.ScreenUpdating = False
    'URL de départ
    vUrl = "http://www.geny.com/reunions-courses-pmu"
    'Ouvre la page web dans IE de façon invisible
    Set IE = CreateObject("internetExplorer.Application")
    IE.Visible = False
    'Ouvrir la page Web
    IE.Navigate vUrl
    Do Until IE.ReadyState = READYSTATE_COMPLETE
        DoEvents
    Loop
    Set IEdoc = IE.Document
    vUrl = "http://www.geny.com/partants-pmu/"
    'Mémoriser les liens utiles
    With ActiveSheet.ComboBox1
        .Clear
        .ColumnCount = 2
        .BoundColumn = 2
        .Style = fmStyleDropDownList
        .AddItem "< choisir une course >"
        For Each O In IEdoc.Links
            If O.href Like vUrl & "*" Then
                T = Mid(O.href, Len(vUrl) + 1)
                T = Left(T, InStrRev(T, "_") - 1)
                .AddItem T
                .List(.ListCount - 1, 1) = O.href
            End If
        Next O
        .ListIndex = 0
    End With
    'Quitter IE
    Set IEdoc = Nothing
    IE.Quit
    Set IE = Nothing
    Application.ScreenUpdating = True
    MsgBox "Liste mise à jour avec succès !" & vbLf & vbLf & "- Choisissez une course dans la liste," & vbLf & "- Cliquez ensuite sur « Stats Partants »  " & vbLf & "- Puis, patientez ...  ", vbInformation + vbOKOnly, "myDearFriend!  -  www.mdf-xlpages.com"
End Sub

Sub RecupPartants()
Dim Plage As Range
Dim TabTemp As Variant
Dim vUrl As String
Dim DernLign As Long, L As Long
Dim DernCol As Integer
    Application.ScreenUpdating = False
    With ActiveSheet
        'Récupère tableau des partants
        .Range("15:100").Delete
        With .ComboBox1
            If .ListIndex < 1 Then Exit Sub
            vUrl = .Value
        End With
        With .QueryTables.Add(Connection:="URL;" & vUrl, Destination:=.Range("B15"))
            .Name = "mDFquery"
            .FieldNames = True
            .RowNumbers = False
            .FillAdjacentFormulas = False
            .PreserveFormatting = True
            .RefreshOnFileOpen = False
            .BackgroundQuery = False
            .RefreshStyle = xlInsertDeleteCells
            .SavePassword = False
            .SaveData = True
            .AdjustColumnWidth = True
            .RefreshPeriod = 0
            .WebSelectionType = xlSpecifiedTables
            .WebTables = "tableau_partants"
            .WebFormatting = xlWebFormattingAll
            .WebPreFormattedTextToColumns = True
            .WebConsecutiveDelimitersAsOne = False
            .WebSingleBlockTextImport = False
            .WebDisableDateRecognition = False
            .WebDisableRedirections = False
            .Refresh BackgroundQuery:=False
        End With
        'Récupére la carrière de chaque cheval
        DernCol = .Cells(16, .Columns.Count).End(xlToLeft).Column
        DernLign = .Cells(.Rows.Count, 2).End(xlUp).Row
        Set Plage = .Range(.Cells(17, 2), .Cells(DernLign, DernCol + 3))
        TabTemp = Plage.Value
        For L = 1 To UBound(TabTemp)
            vUrl = Plage.Cells(L, 2).Hyperlinks(1).Address
            RecupCarriere vUrl, DernLign + 1
            TabTemp(L, DernCol) = .Cells(DernLign + 2, 3)
            TabTemp(L, DernCol + 1) = .Cells(DernLign + 2, 4)
            TabTemp(L, DernCol + 2) = .Cells(DernLign + 2, 5)
        Next L
        Plage.Value = TabTemp
        'Mise en forme
        .Range(.Cells(DernLign + 1, 3), .Cells(DernLign + 1, 5)).Copy Destination:=.Cells(Plage(1).Row - 1, DernCol + 1)
        .Range(DernLign + 1 & ":1000").Delete
        .Columns(DernCol).Copy
        .Range(.Cells(1, DernCol + 1), .Cells(1, DernCol + 3)).EntireColumn.PasteSpecial Paste:=xlPasteFormats
        .Cells.Hyperlinks.Delete
        With Plage.Borders()
            .LineStyle = xlContinuous
            .Weight = xlThin
            .ColorIndex = xlAutomatic
        End With
        .Cells.EntireColumn.AutoFit
        .Cells(15, 2).Select
    End With
    Application.ScreenUpdating = True
    Beep
End Sub

Sub RecupCarriere(vUrl As String, Lign As Long)
    With ActiveSheet
        .Range(Lign & ":1000").Delete
        With .QueryTables.Add(Connection:="URL;" & vUrl, Destination:=.Cells(Lign, 2))
            .Name = "mDFquery"
            .FieldNames = True
            .RowNumbers = False
            .FillAdjacentFormulas = False
            .PreserveFormatting = False
            .RefreshOnFileOpen = False
            .BackgroundQuery = False
            .RefreshStyle = xlInsertDeleteCells
            .SavePassword = False
            .SaveData = True
            .AdjustColumnWidth = True
            .RefreshPeriod = 0
            .WebSelectionType = xlSpecifiedTables
            .WebFormatting = xlWebFormattingRTF
            .WebTables = "2"
            .WebPreFormattedTextToColumns = True
            .WebConsecutiveDelimitersAsOne = False
            .WebSingleBlockTextImport = False
            .WebDisableDateRecognition = False
            .WebDisableRedirections = False
            .Refresh BackgroundQuery:=False
        End With
    End With
End Sub


Cordialement,



Pièce jointe:
zip mDF_RecupWeb GenyCom.zip   [ Taille: 26.99 Ko - Téléchargements: 4451 ]
Didier_mDF
Image redimensionnée
Le Webmaster

La réponse vous satisfait ? Merci de revenir solder le sujet en [résolu], voir ce lien
Hors Ligne
 Rapport   Haut 

Re: Récupération de données turfiques du site gény course
#5
chakir123
Aspirant XLPages

Inscription: 05/10/2011

Messages: 35

Système d'exploitation:
PC
Version Excel utilisée:
2003, 2007
Posté le : 17-10-2011 23h12
Bonsoir Didier,

je suis patient comme j'avais pu te dire lors de mon premier post.
Merci pour ton ENORME travail !!!!!!!
Je t'en suis très reconnaissant, je ne sais pas comment tu as fais pour cerner ne serait-ce que ma demande, c'était exactement cela que je souhaitais !
Grâce à toi je vais gagner un temps fou, jamais j'aurais pensé que c'était possible. EPOUSTOUFLANT (je serais imcapable d'en faire le 1/10 eme).

Je ne sais pas comment te remercier, en tout cas saches que tu viens de faire le bonheur d'un turfiste.

Mille fois merci!

nb : Penses tu qu'un jour si le site de geny change je pourrais grâce à ton code retrouver le même principe?
Avec ta permission puis-je partager gratuitement ce fichier avec mes amis turfistes?
Hors Ligne
 Rapport   Haut 

Re: Récupération de données turfiques du site gény course
#6
myDearFriend!
Webmestre

Inscription: 18/05/2006
De Saône-et-Loire (71)

Messages: 1539

Système d'exploitation:
PC
Version Excel utilisée:
97, 2000, 2002, 2003, 2007, 2010, 2013, 2016 et 365
Posté le : 17-10-2011 23h50
Bonsoir chakir123, le Forum,

Citation :
chakir123 a écrit :
Bonsoir Didier,

je suis patient comme j'avais pu te dire lors de mon premier post.
Merci pour ton ENORME travail !!!!!!!
Je t'en suis très reconnaissant, je ne sais pas comment tu as fais pour cerner ne serait-ce que ma demande, c'était exactement cela que je souhaitais !
Grâce à toi je vais gagner un temps fou, jamais j'aurais pensé que c'était possible. EPOUSTOUFLANT (je serais imcapable d'en faire le 1/10 eme).

Je ne sais pas comment te remercier, en tout cas saches que tu viens de faire le bonheur d'un turfiste.

Mille fois merci!

En règle générale, le présent forum n'est pas vraiment fait pour fournir des macros de ce type (« clé en main »), mais s'adresse plutôt à celles et ceux qui veulent apprendre Excel ou VBA et se trouvent en difficultés... Mais devant un tel enthousiasme, que dire ? 


Citation :
chakir123 a écrit :
nb : Penses tu qu'un jour si le site de geny change je pourrais grâce à ton code retrouver le même principe?


Si le site Geny.com change, il faudra sans doute réadapter cette macro. Quant à savoir si le principe adopté sera toujours fonctionnel dans ce cas, je ne saurais te dire... tout dépend des modifications qui pourraient être apportées au site.

Citation :
chakir123 a écrit :
Avec ta permission puis-je partager gratuitement ce fichier avec mes amis turfistes?

J'apprécierais davantage que tu donnes le lien (URL) du présent fil de discussions à tes amis turfistes, ainsi ils pourront venir télécharger librement eux-mêmes le fichier en pièce jointe.
L'objectif du présent site (comme tout autre site), c'est d'être connu et fréquenté par le plus grand nombre.
Cela serait d'ailleurs un bon moyen de montrer de la reconnaissance pour service rendu.

Dans l'attente, et si tu penses avoir obtenu réponse qui te convienne, je te remercie de mettre en pratique ce qui est indiqué au bas de ma signature...

Bien cordialement,

Didier_mDF
Image redimensionnée
Le Webmaster

La réponse vous satisfait ? Merci de revenir solder le sujet en [résolu], voir ce lien
Hors Ligne
 Rapport   Haut 

Re: Récupération de données turfiques du site gény course
#7
chakir123
Aspirant XLPages

Inscription: 05/10/2011

Messages: 35

Système d'exploitation:
PC
Version Excel utilisée:
2003, 2007
Posté le : 18-10-2011 01h01
Merci Encore Didier,
Je ne manquerais pas de mettre le lien afin que les amis turfistes passe prendre le fichier ici.

Sinon par ou faut 'il commencer pour apprendre la programmation en VBA?
Que conseilles-tu?
Hors Ligne
 Rapport   Haut 

Re: Récupération de données turfiques du site gény course
#8
myDearFriend!
Webmestre

Inscription: 18/05/2006
De Saône-et-Loire (71)

Messages: 1539

Système d'exploitation:
PC
Version Excel utilisée:
97, 2000, 2002, 2003, 2007, 2010, 2013, 2016 et 365
Posté le : 19-10-2011 10h21
Bonjour chakir123, le Forum,

Voici ce qu'il m'est arrivé de répondre quand on m'a posé cette question :
Citation :
myDearFriend! a écrit :
Voici la liste des prérequis qui me semblent indispensables si tu souhaites apprendre VBA, il te faut :
  • un bon projet que tu construiras toi-même, de façon progressive au fur et à mesure de tes connaissances (pas la peine d'aller trop vite si tu souhaites vraiment comprendre et apprendre).
  • un bonne habitude de consulter l'aide VBA (indispensable !).
  • une fréquentation régulière des forums de discussions Excel, ici ou ailleurs (on apprend plein de choses dans ces communautés). Par ailleurs, n'hésite pas à exposer dans ces endroits les points que tu ne comprends pas : nombre de bénévoles partageront volontiers leurs connaissances et leur expérience. Pour rappel, ici j'ai créé un forum "Espace débutants", il est fait essentiellement pour ça. Par ailleurs, c'est là que je puise les idées de tutoriels pour le présent site, alors n'hésite pas.
  • un bon bouquin sur les bases de la programmation VBA (pourquoi pas ?).
  • Et enfin,... de la patience et de la persévérance !
A ceci, j'ajouterais que tu peux déjà trouver des choses intéressantes dans les Tutoriels XLpages (Pub !) et particulièrement dans la rubrique VBA pour débutants. Mais il existe plein d'autres endroits sur le net dans lesquels puiser la connaissance partagée (voir la rubrique "liens Web" de ce site notamment). Il te faut par contre, te confronter souvent à de la documentation dans la langue de Shakespeare. C'est comme ça.

Mais avant tout, il te faut déjà maitriser à minima l'utilisation « classique » d'Excel. Dans 99% des cas, VBA est utilisé pour reproduire automatiquement et rapidement les manipulations que tu ferais laborieusement à la main. Aussi, il te faut obligatoirement savoir pratiquer ces manipulations de base avant d'envisager les automatiser...

N'hésites pas à revenir si tu as des questions à poser au fur et à mesure de ton apprentissage...

Cordialement,

Didier_mDF
Image redimensionnée
Le Webmaster

La réponse vous satisfait ? Merci de revenir solder le sujet en [résolu], voir ce lien
Hors Ligne
 Rapport   Haut 

Re: Récupération de données turfiques du site gény course
#9
chakir123
Aspirant XLPages

Inscription: 05/10/2011

Messages: 35

Système d'exploitation:
PC
Version Excel utilisée:
2003, 2007
Posté le : 19-10-2011 21h54
Salut Didier,

Merci pour tes conseils, je vais les suivre pas à pas, vu la complexité de la matière...
En tout cas je te remercie pour ta gentillesse et ta pédagogie (tu es prof je crois.
En tous cas t'es un bon prof comme on aurait aimé en avoir dans notre vie scolaire.

Bonne continuation, je ne manquerais pas de venir régulièrement sur le site.
MERCI
Hors Ligne
 Rapport   Haut 

Re: Récupération de données turfiques du site gény course
#10
kiwi117
Débutant XLPages

Inscription: 06/01/2013

Messages: 2

Système d'exploitation:
PC
Version Excel utilisée:
2007
Posté le : 06-01-2013 18h33
Bonjour,


Nouveau venu sur le site je me permets de venir vous demander de l'aide. Je suis en train d'étudier le VBA grâve au livre "macros et langage VBA" de F. LE GUEN mais je n'en suis qu'aux balbutiements et donc très peu agguérri aux rouages de ce langage.
Aussi, turfiste passionné, j'aimerai, comme mon collègue initiateur de ce fil de discussion pouvoir importer les données de Geny.com. Je peux grace à votre travail et votre code récupérer les données des courses du jour mais j'aimerai pouvoir recupérer les données des courses passées. Sur le site www.geny.com nous pouvons , dans l'onglet "Quinté+/réunion PMU"  avoir accès à toutes les journées de courses sur plusieurs années en arrière en ouvrant le calendrier se trouvant en haut et à droite de la page Web. J'ai essayé de modifier le code en rajoutant la date en fin d'adresse mais ça ne fonctionne pas.

De plus, j'aimerai si cela est possible , récuperer plus d'infos comme les places obtenues sur les 10 dernières courses courues pour chaque partant et pour la dernière (celle qui précède la course à étudier)  la côte du cheval et l'allocation de la course. Enfin j'aimerai pouvoir récuperer pour chaque partant son record absolu (chrono  voir onglet "record") , son record sur la distance et sur le parcours.

Rien que ça...

Je vais continuer à chercher de mon côté avec votre code mis à disposition.
Merci d'avance et bravo pour vos tutoriels très pédagogiques.

Meilleurs voeux à vous tous et longue vie à ce forum passionnant.
Marc
Hors Ligne
 Rapport   Haut 


Vous pouvez voir les sujets.
Vous ne pouvez pas débuter de nouveaux sujets.
Vous ne pouvez pas répondre aux contributions.
Vous ne pouvez pas éditer vos contributions.
Vous ne pouvez pas effacez vos contributions.
Vous ne pouvez pas ajouter de nouveaux sondages.
Vous ne pouvez pas voter en sondage.
Vous ne pouvez pas attacher des fichiers à vos contributions.
Vous ne pouvez pas poster sans approbation.

[Recherche avancée]


Qui consulte actuellement ce sujet ?   1 Utilisateur(s) anonymes